linux-0.11分析:boot文件 head.s 第三篇随笔

head.s

参考 [github这个博主的][ https://github.com/sunym1993/flash-linux0.11-talk ]

  1. 改变栈顶位置

    _pg_dir:
    startup_32:
    	movl $0x10,%eax
    	mov %ax,%ds
    	mov %ax,%es
    	mov %ax,%fs
    	mov %ax,%gs
    	lss _stack_start,%esp
    

    先是分别ds,es,fs,gs的值都置成了0x10

    然后这段·lss _stack_start,esp相当于把ss:sep这个栈顶指针指向 _stack_start这个位置,而这个位置在head.s中找不到,它在sched.c

    long user_stack [ PAGE_SIZE>>2 ] ;
    struct {
    	long * a;
    	short b;
    	} stack_start = { & user_stack [PAGE_SIZE>>2] , 0x10 };
    

    在linux-0.11文件kernel文件下的sched.c,在67~72行左右;

  2. 从新设置idt和gdt;

    call setup_idt
    call setup_gdt
    movl $0x10,%eax	; 重新加载所有段寄存器
    mov %ax,%ds	; 更改gdt后。CS已经
    mov %ax,%es	; 在“setup\u gdt”中重新加载
    mov %ax,%fs
    mov %ax,%gs
    lss _stack_start,%esp
    

    前两行分别在设置 idt 和 gdt的值

    后面有重新设置了ds,es,fs,gs因为在设置idt和gdt中改变了这些值,而这里在进行call操作时,并没有压栈,所以需要从新设置,还有从新设置栈顶

  3. 先看看dit的设置

    setup_idt:
    	lea ignore_int,%edx
    	movl $0x00080000,%eax
    	movw %dx,%ax	/* selector = 0x0008 = cs */
    	movw $0x8E00,%dx	/* interrupt gate - dpl=0, present */
    	lea _idt,%edi
    	mov $256,%ecx
    rp_sidt:
    	movl %eax,(%edi)
    	movl %edx,4(%edi)
    	addl $8,%edi
    	dec %ecx
    	jne rp_sidt
    	lidt idt_descr
    	ret
    

    设置了 **256 **个中断描述符, 让每一个中断描述符中的中断程序例程都指向一个 ignore_int 的函数地址

    看看 ignore_int

    ignore_int:
    	pushl %eax
    	pushl %ecx
    	pushl %edx
    	push %ds
    	push %es
    	push %fs
    	movl $0x10,%eax
    	mov %ax,%ds
    	mov %ax,%es
    	mov %ax,%fs
    	pushl $int_msg
    	call _printk
    	popl %eax
    	pop %fs
    	pop %es
    	pop %ds
    	popl %edx
    	popl %ecx
    	popl %eax
    	iret
    

    也就call了_printk这个地址这是一个打印的操作.....

  4. 再看看gdt的设置

    setup_gdt:
    	lgdt gdt_descr
    	ret
    gdt_descr:
    	.word 256*8-1	# so does gdt (not that that's any
    	.long _gdt	# magic number, but it works for me :^)
    	.align 3
    _gdt:	
    	.quad 0x0000000000000000	/* NULL descriptor */
    	.quad 0x00c09a0000000fff	/* 16Mb */
    	.quad 0x00c0920000000fff	/* 16Mb */
    	.quad 0x0000000000000000	/* TEMPORARY - don't use */
    	.fill 252,8,0
    

    跟之前设置的gdt一毛一样,只是在内存中的位置变了

    然后看看内存的改变的样子

  5. 然后看看进入main.c的那段代码

    after_page_tables:
    	pushl $0	# These are the parameters to main :-)
    	pushl $0
    	pushl $0
    	pushl $L6	# return address for main, if it decides to.
    	pushl $_main
    	jmp setup_paging
    L6:
    	jmp L6	
    

    把_main的地址入栈,当进行完jmp setup_paging这段操作后面弹栈就进入main.c函数了

  6. 接下里就看看setup_paging这个函数吧

    setup_paging:
    	movl $1024*5,%ecx	/* 5 pages - pg_dir+4 page tables */
    	xorl %eax,%eax
    	xorl %edi,%edi	/* pg_dir is at 0x000 */
    	cld;rep;stosl
    	movl $pg0+7,_pg_dir	/* set present bit/user r/w */
    	movl $pg1+7,_pg_dir+4	/* --------- " " --------- */
    	movl $pg2+7,_pg_dir+8	/* --------- " " --------- */
    	movl $pg3+7,_pg_dir+12	/* --------- " " --------- */
    	movl $pg3+4092,%edi
    	movl $0xfff007,%eax	/* 16Mb - 4096 + 7 (r/w user,p) */
    	std
    1:	stosl	/* fill pages backwards - more efficient :-) */
    	subl $0x1000,%eax
    	jge 1b
    	xorl %eax,%eax	/* pg_dir is at 0x0000 */
    	movl %eax,%cr3	/* cr3 - page directory start */
    	movl %cr0,%eax
    	orl $0x80000000,%eax
    	movl %eax,%cr0	/* set paging (PG) bit */
    	ret	
    

    这是在设置页目录和页表;

    分页机制也是相当于改变了物理寻址的方式,或者说给物理寻址多加了一步

    先看看前面的分段机制:

    段选择子:高12位 => 存储的是段描述符的索引;段选择子例如:ds,cs,es等等

    通过段描述符的索引找到段描述符:在得到 段基址 + 偏移地址 = 物理地址

    那么现在这个分页机制页数类似的,只不过在是在分段机制的后面

    先来说一说官方的词语:逻辑地址,线性地址,虚拟地址,物理地址

    逻辑地址:也就是我们程序员写程序时给出的地址

    线性地址:吧逻辑地址经过分段机制后的出来的就是线性地址 32位

    虚拟地址:这个地址其实就是如果你开启了分页机制,那么刚刚得到的线性地址就是虚拟地址,只是改了一个名字而已

    物理地址:如果不经过分页机制,那么刚刚得到的线性地址就是物理地址;如果经过分页机制,那么刚刚的线性地址(虚拟地址)经过分页机制得到的就是物理地址;

    下面通过一张图来清晰的看看:

    现在来看看分页机制如何寻址的:

    先把线性地址(32位)分段:高10位;中间10位;最后12位

    1. 用高10位去页目录表寻找页目录项
    2. 然后用页目录项拼接上中间10位得到的值,去页表中寻找页表项
    3. 最后用页表项加上最后12位的偏移地址得到就是物理地址

    而这一切的操作,都由计算机的一个硬件叫 MMU,中文名字叫内存管理单元,有时也叫 PMMU,分页内存管理单元。由这个部件来负责将虚拟地址转换为物理地址。

    那怎么才算开启了分页机制了,就要用到这个cr0寄存器的PG位了

    由于linux0.11 用的是20位物理地址,所以大小为16MB

    1 个页目录表最多包含 1024 个页目录项(也就是 1024 个页表),1 个页表最多包含 1024 个页表项(也就是 1024 个页),1 页为 4KB(因为有 12 位偏移地址),因此,16M 的地址空间可以用 1 个页目录表 + 4 个页表搞定。

    4(页表数)* 1024(页表项数) * 4KB(一页大小)= 16MB

    .org 0x1000
    pg0:
    .org 0x2000
    pg1:
    .org 0x3000
    pg2:
    .org 0x4000
    pg3:
    .org 0x5000
    

    开始的位置就存储在cr3寄存器

    首先页目录存在 : 0x0000 ~ 0x1000

    而四个页表项存在:0x1000 ~ 0x2000;0x2000 ~ 0x3000;0x3000 ~ 0x4000;0x4000 ~ 0x5000

    注意:这里覆盖了0x0000~0x5000的System的代码因为这些代码已经运行了,也没有保存什么有用的东西,所有可以覆盖了

    那么现在再来看看内存的布局,就要进入main.c函数了

    1. 再次看看最后进入main.c的那段代码吧

      after_page_tables:
      	pushl $0	# These are the parameters to main :-)
      	pushl $0
      	pushl $0
      	pushl $L6	# return address for main, if it decides to.
      	pushl $_main
      	jmp setup_paging
      	
      setup_paging:
      	..... 此处省略一大段
      	ret	
      
      • 可以看到在jmp进入setup_paging之前先把 0,0,0, L6 和main.c的地址压栈

      • 最后在执行完 setup_paging 之后又ret 弹栈顶元素就是main.c的地址

      • 至此就彻底进入了main.c的代码中,在上面也不会ret结束,在上面就等待着其他用于程序调用操作系统,但是也并非这么简单

      最后来回忆一哈,boot这个文件下bootsect.s、setup.s、head.s都做了些什么!!!(补充哈,这是在linux-0.11操作系统下哟);最后内存的样子在上面了

作者:水三丫原文地址:https://www.cnblogs.com/shuisanya/p/16541884.html

%s 个评论

要回复文章请先登录注册